float globalAngle = 0.0f;

int numButtonLists=10;
CvButtonList [] buttonLists;

int previousColourSet=0;
int previousArmMode=0;
int previousSpinMode=0;

int BL_SpinControl = 0;
int BL_Depth = 1;
int BL_SpinAlternate = 2;
int BL_ClearMode = 3;
int BL_LineMode = 4;
int BL_NodeMode = 5;
int BL_ArmCountMode = 6;
int BL_SizeReduction = 7;
int BL_ColorSet = 9;

color COL_Background;
color COL_Line;
color COL_Node;
color COL_ButtonOutline;
color COL_ButtonOn;
color COL_ButtonOff;

BFont mainFont;

int [] randomArms = {3,1,1,2,5,6,7,8,9,10};
float [] randomSpin = {1.0f,-1.0f,1.0f,-1.0f,1.0f,-1.0f,1.0f,-1.0f,1.0f,-1.0f};

void setup()
{
  size(500,500);

  buttonLists = new CvButtonList[numButtonLists];
  for (int i=0; i<numButtonLists; i++)
  {
    buttonLists[i] = new CvButtonList(10+i*(int)(width/11),10,1); // 35
  }

  mainFont = loadFont("Trebuchet_MS.vlw");
  textFont(mainFont, 40);

  //smooth();

  setColors(0);

  buttonLists[BL_SpinControl].numItems=2;
  buttonLists[BL_Depth].numItems=7;
  buttonLists[BL_SpinAlternate].numItems=3;
  buttonLists[BL_ClearMode].numItems=1;
  buttonLists[BL_LineMode].numItems=2;
  buttonLists[BL_NodeMode].numItems=3;
  buttonLists[BL_ArmCountMode].numItems=8;
  buttonLists[BL_SizeReduction].numItems=5;
  buttonLists[BL_ColorSet].numItems=4;

  buttonLists[BL_SpinControl].listName="spin";
  buttonLists[BL_SpinControl].subNames[0]="automatic";
  buttonLists[BL_SpinControl].subNames[1]="mouse";

  buttonLists[BL_Depth].listName="draw depth";
  buttonLists[BL_Depth].subNames[0]="1";
  buttonLists[BL_Depth].subNames[1]="2";
  buttonLists[BL_Depth].subNames[2]="3";
  buttonLists[BL_Depth].subNames[3]="4";
  buttonLists[BL_Depth].subNames[4]="5";
  buttonLists[BL_Depth].subNames[5]="6";
  buttonLists[BL_Depth].subNames[6]="7";
  buttonLists[BL_Depth].subNames[7]="8";

  buttonLists[BL_SpinAlternate].listName="spin mode";
  buttonLists[BL_SpinAlternate].subNames[0]="normal";
  buttonLists[BL_SpinAlternate].subNames[1]="alternating";
  buttonLists[BL_SpinAlternate].subNames[2]="randomise list";

  buttonLists[BL_ClearMode].listName="clear";

  buttonLists[BL_LineMode].listName="lines";
  buttonLists[BL_LineMode].subNames[0]="off";
  buttonLists[BL_LineMode].subNames[1]="on";

  buttonLists[BL_NodeMode].listName="nodes";
  buttonLists[BL_NodeMode].subNames[0]="off";
  buttonLists[BL_NodeMode].subNames[1]="square";
  buttonLists[BL_NodeMode].subNames[2]="circle";

  buttonLists[BL_ArmCountMode].listName="arm count";
  buttonLists[BL_ArmCountMode].subNames[0]="mode 1";
  buttonLists[BL_ArmCountMode].subNames[1]="mode 2";
  buttonLists[BL_ArmCountMode].subNames[2]="mode 3";
  buttonLists[BL_ArmCountMode].subNames[3]="mode 4";
  buttonLists[BL_ArmCountMode].subNames[4]="mode 5";
  buttonLists[BL_ArmCountMode].subNames[5]="mode 6";
  buttonLists[BL_ArmCountMode].subNames[6]="mode 7";
  buttonLists[BL_ArmCountMode].subNames[7]="randomise generation";
  
  buttonLists[BL_SizeReduction].listName="scaler";
  buttonLists[BL_SizeReduction].subNames[0]="1";
  buttonLists[BL_SizeReduction].subNames[1]="2";
  buttonLists[BL_SizeReduction].subNames[2]="3";
  buttonLists[BL_SizeReduction].subNames[3]="4";
  buttonLists[BL_SizeReduction].subNames[4]="5";

  buttonLists[BL_ColorSet].listName="colours";
  buttonLists[BL_ColorSet].subNames[0]="set 1";
  buttonLists[BL_ColorSet].subNames[1]="set 2";
  buttonLists[BL_ColorSet].subNames[2]="set 3";
  buttonLists[BL_ColorSet].subNames[3]="randomise";

  setButtonPreset(0);

}

void setButtonPreset(int mode)
{
  if (mode==0)
  {
    buttonLists[BL_SpinControl].selectedItem=0;
    buttonLists[BL_Depth].selectedItem=4;
    buttonLists[BL_SpinAlternate].selectedItem=0;
    buttonLists[BL_ClearMode].selectedItem=0;
    buttonLists[BL_LineMode].selectedItem=1;
    buttonLists[BL_NodeMode].selectedItem=2;
    buttonLists[BL_ArmCountMode].selectedItem=3;
    buttonLists[BL_SizeReduction].selectedItem=1;
    buttonLists[BL_ColorSet].selectedItem=0;
  }
  else if (mode==-1)
  {
    buttonLists[BL_SpinControl].selectedItem=0;
    buttonLists[BL_Depth].randomise();
    buttonLists[BL_SpinAlternate].randomise();
    buttonLists[BL_ClearMode].randomise();
    buttonLists[BL_LineMode].randomise();
    buttonLists[BL_NodeMode].randomise();
    buttonLists[BL_ArmCountMode].randomise();
    buttonLists[BL_SizeReduction].randomise();
    buttonLists[BL_ColorSet].randomise();

    if (buttonLists[BL_Depth].selectedItem<3) buttonLists[BL_Depth].selectedItem=3;
    if (buttonLists[BL_NodeMode].selectedItem==0) buttonLists[BL_NodeMode].selectedItem=1;
    if (random(1.0f)<0.3f) buttonLists[BL_ArmCountMode].selectedItem=7;
  }
}

void setColors(int set)
{
  if (set==0)
  {
    COL_Background = color(148,148,148);
    COL_Line = color(1,2,4);
    COL_Node = color(51,105,153);
    COL_ButtonOutline = color(0,0,0);
    COL_ButtonOff = color(140,140,140);
    COL_ButtonOn = color(158,158,158);
  }
  else if (set==1)
  {
    COL_Background = color(255,153,51);
    COL_Line = color(1,128,128);
    COL_Node = color(28,28,28);
    COL_ButtonOutline = color(0,0,0);
    COL_ButtonOff = color(170,170,170);
    COL_ButtonOn = color(238,238,238);
  }
  else if (set==2)
  {
    COL_Background = color(237,217,193);
    COL_Line = color(255,255,255);
    COL_Node = color(224,57,39);
    COL_ButtonOutline = color(0,0,0);
    COL_ButtonOff = color(237-10,217-10,193-10);
    COL_ButtonOn = color(237+10,217+10,193+10);
  }
  else if (set==3)
  {
    float br,bg,bb,bbb;
    br=random(1.0f)*255;
    bg=random(1.0f)*255;
    bb=random(1.0f)*255;
    bbb=random(1.0f)*30;
    COL_Background = color(br,bg,bb);
    COL_Line = color(random(1.0f)*255,random(1.0f)*255,random(1.0f)*255);
    COL_Node = color(random(1.0f)*255,random(1.0f)*255,random(1.0f)*255);
    COL_ButtonOutline = color(br*0.3,bg*0.3,bb*0.3);
    COL_ButtonOff = color(br-bbb,bg-bbb,bb-bbb);
    COL_ButtonOn = color(br+bbb,bg+bbb,bb+bbb);
  }
}

void keyPressed()
{
  if (key=='r') setButtonPreset(-1);

}

void loop()
{
  // background mode
  //  if (buttonLists[BL_ClearMode].selectedItem==0) fill(COL_Background);
  // else fill(20,20,20,10);
  fill(COL_Background);
  noStroke();
  rectMode(CORNER);
  rect(0,0,width,height);

  // Tick and draw all buttons first - we want them under the main object.
  for (int i=0;i<numButtonLists;i++)
  buttonLists[i].tick();

  // auto rotate or use mouse?
  if (buttonLists[BL_SpinControl].selectedItem==0)
  globalAngle+=0.003f;
  else
  globalAngle=mouseX/500.0f;

  // Draw main object
  recurse(width/2, height/2, 0.0f, width/5, 0);

  if (previousColourSet!=buttonLists[BL_ColorSet].selectedItem ||
  (buttonLists[BL_ColorSet].mouseOver == 3 && mousePressed))
  {
    previousColourSet=buttonLists[BL_ColorSet].selectedItem;
    setColors(buttonLists[BL_ColorSet].selectedItem);
  }

  if (previousArmMode!=buttonLists[BL_ArmCountMode].selectedItem ||
  (buttonLists[BL_ArmCountMode].mouseOver == 7 && mousePressed))
  {
    previousArmMode=buttonLists[BL_ArmCountMode].selectedItem;
    for (int i=0;i<10;i++)
    {
      randomArms[i] = 1+(int)(random(1.0f)*5);
    }
  }

  if (previousSpinMode!=buttonLists[BL_SpinAlternate].selectedItem ||
  (buttonLists[BL_SpinAlternate].mouseOver == 2 && mousePressed))
  {
    previousSpinMode=buttonLists[BL_SpinAlternate].selectedItem;
    for (int i=0;i<10;i++)
    {
      randomSpin[i] = 1.0f;
      if (random(1.0f)<0.5f) randomSpin[i] = -1.0f;
    }
  }

  return;

}

void drawBlob(int x, int y, int r, int _red, int _green, int _blue, int _alpha)
{
  r=20;
  noStroke();
  int r2 = r*2;
  float d,i;
  for (int yy=0;yy<r2;yy++)
  {
    for (int xx=0;xx<r2;xx++)
    {
      d = sqrt(sq(r-yy)+sq(r-xx))/(float)r;
      if (d>1.0f) continue;// d=1.0f;
      d=1.0f-d;
      d=d*d*d;
      d=1.0f-d;
      i=1.0f-d;
      fill(_red, _green, _blue, _alpha*i);
      rect(x+xx-r,y+yy-r,1,1);
    }
  }

}

float [] sizeReductions={0.5f,0.6f,0.65f,0.7f,0.75f};

void recurse(float x, float y, float angle, float radius, int level)
{
  // Exit if we have reached recurse limit.
  if (level>buttonLists[BL_Depth].selectedItem) return;

  int arms = 2;//5-level;//+3;//3;
  float xo,yo,angleShift,spinDir=1.0f;
  float sizeReduction = sizeReductions[buttonLists[BL_SizeReduction].selectedItem];

  // arm mode
  switch (buttonLists[BL_ArmCountMode].selectedItem)
  {
    case 0:
    arms=2;
    break;
    case 1:
    arms=3;
    break;
    case 2:
    arms=4;
    break;
    case 3:
    arms=5-level;
    break;
    case 4:
    arms=level+2;
    break;
    case 5:
    arms=level+3;
    break;
    case 6:
    arms=1+level/3;
    break;
    case 7:
    arms=randomArms[level];
    break;
  }

  if (arms>5) arms=5;
  if (arms<1) arms=1;

  spinDir=1.0f;
  if (buttonLists[BL_SpinAlternate].selectedItem==1)
  {
    if (level==1 || level==3 || level==5 || level==7 || level==9) spinDir=-1.0f;
  }
  else if (buttonLists[BL_SpinAlternate].selectedItem==2)
  {
    spinDir = randomSpin[level];
  }

  for (int i =0; i<arms;i++)
  {
    angleShift = globalAngle + ((1.0f/arms)*i);
    xo=sin(2*PI*((angle*spinDir)+angleShift))*radius;
    yo=cos(2*PI*((angle*spinDir)+angleShift))*radius;

    stroke(COL_Line);

    if (buttonLists[BL_LineMode].selectedItem==1)
    line(x,y,x+xo,y+yo);

    recurse(x+xo, y+yo, angle+angleShift, radius*sizeReduction, level+1);
  }

  noStroke();

  // draw nodes
  if (level>0)
  {
    if (buttonLists[BL_NodeMode].selectedItem==1)
    {
      fill(COL_Node);
      rectMode(CENTER_DIAMETER);
      rect(x,y,radius/3.0f+1,radius/3.0f+1);
    }
    else if (buttonLists[BL_NodeMode].selectedItem==2)
    {
      //drawBlob((int)x, (int)y, (int)(radius*0.1f), 0, 0, 00, 250);
      fill(COL_Node);
      ellipseMode(CENTER_DIAMETER);
      ellipse(x,y,radius/3.0f+1,radius/3.0f+1);
    }
  }

}

/////////////////////////////////////////////////

class CvButtonList
{
  CvButtonList(int x, int y, int num)
  {
    borderSize=4;
    buttonSize=(int)(width/20.0f);//18;
    //
    xPos = x;
    yPos = y;
    numItems=num;
    mouseOver=-1;
    selectedItem=0;
    totalButtonSize = buttonSize+borderSize+borderSize;
    subNames = new String[20];
    for (int i=0;i<20;i++) subNames[i]=new String("null");
    listName="null";
  }

  void tick()
  {

    if (mouseX>xPos && mouseX<xPos+(totalButtonSize) &&
    mouseY>yPos && mouseY<yPos+(totalButtonSize)*numItems)
    {
      mouseOver=(mouseY-yPos)/totalButtonSize;
      if (mousePressed) selectedItem=mouseOver;

      if (mouseOver!=-1)
      {
        fill(COL_ButtonOn);
        text(listName+" / "+subNames[mouseOver], 20, height-20);
        fill(COL_ButtonOff);
        text(listName+" / "+subNames[mouseOver], 20+2, height-20+2);
      }
    }
    else
    {
      mouseOver=-1;
    }

    draw();
  }

  void draw()
  {
    int x,y;
    for (int i=0;i<numItems;i++)
    {
      noStroke();
      fill(COL_ButtonOff);
      if (i==mouseOver)
      stroke(COL_ButtonOutline);
      if (i==selectedItem)
      fill(COL_ButtonOn);

      x = xPos+borderSize;
      y = yPos+borderSize;
      y += i*(totalButtonSize);
      rect(x,y,buttonSize,buttonSize);
    }
  }

  int getSelection()
  {
    return selectedItem;
  }

  void randomise()
  {
    selectedItem = (int)((numItems+1) * random(1.0f));
    if (selectedItem>numItems-1) selectedItem=numItems-1;
  }

  int xPos,yPos;
  int numItems;
  int mouseOver;
  int selectedItem;
  int borderSize;
  int buttonSize;
  int totalButtonSize;
  String listName;
  String [] subNames;
};